Vim のターミナルウィンドウの文字色を設定する

はじめに

Vim 8.1 がリリースされましたね。目玉機能の一つとしてターミナルウィンドウが挙げられています。 Vim 8.0 から存在していましたが、ついに実験的機能ではなくなった、ということでしょうか。

f:id:machakann:20180519224618j:plain

実はこのターミナルウィンドウの文字色は、設定によって変更できます。しかし、これは :highlight コマンドとは異なる方法で管理され、しかも、適切に扱うにはある程度 Vim script の知識が必要になります。なので、ここに簡単にまとめておこうと思います。

ただし、注意する点として以下の機能を使うためには gvim を使用しているか、 'termguicolors' オプションが使用可能でオンになっている必要があります。

ユーザーによる設定

各文字色の指定には g:terminal_ansi_colors 変数を使います。これは十六要素のリストで、各要素は色指定のための文字列です。基本的には #RRGGBB 形式の七文字で指定します。

let g:terminal_ansi_colors = [
  \ "#0c0c0c", "#c50f1f", "#13a10e", "#c19c00",
  \ "#0037da", "#881798", "#3a96dd", "#cccccc",
  \ "#767676", "#e74856", "#16c60c", "#eadf84",
  \ "#3b78ff", "#b4009e", "#61d6d6", "#e8e8e8"
  \ ]

各要素は次のように各文字色に対応しています。

インデックス
0 black
1 dark red
2 dark green
3 brown
4 dark blue
5 dark magenta
6 dark cyan
7 light grey
8 dark grey
9 red
10 green
11 yellow
12 blue
13 magenta
14 cyan
15 white

つまり、このような対応になります。

let g:terminal_ansi_colors = [
  \ "black",     "dark red",     "dark green", "brown",
  \ "dark blue", "dark magenta", "dark cyan",  "light grey",
  \ "dark grey", "red",          "green",      "yellow",
  \ "blue",      "magenta",      "cyan",       "white"
  \ ]

理想的には、ユーザーは何も設定の必要がなく、各カラースキームが適切な色を設定するのが一番良いと思います。しかし、実際にはまだ新しい機能なので、まだすべてのカラースキームファイルが対応しているわけではありません。ひとまず使っているカラースキームで問題がある場合に g:terminal_ansi_colors を設定しましょう。

g:terminal_ansi_colors は vimrc で設定してもカラースキームが上書きしたり、削除したりします。なので、デフォルト設定として次のように設定すると安心です。

if has('terminal')
  function! s:set_default_ansi_colors() abort
    if exists('g:terminal_ansi_colors')
      return
    endif

    let g:terminal_ansi_colors = [
      \ "#0c0c0c", "#c50f1f", "#13a10e", "#c19c00",
      \ "#0037da", "#881798", "#3a96dd", "#cccccc",
      \ "#767676", "#e74856", "#16c60c", "#eadf84",
      \ "#3b78ff", "#b4009e", "#61d6d6", "#e8e8e8"
      \ ]
  endfunction
  call s:set_default_ansi_colors()

  augroup vimrc
    autocmd!
    autocmd ColorScheme * call s:set_default_ansi_colors()
  augroup END
endif

自動コマンドグループ名 (:help :augroup) は各自適切に設定してください。以下のリンクが参考になります。

vimrcアンチパターン · vim-jp/reading-vimrc Wiki · GitHub

おさらい autocmd/augroup - Qiita

【一人 vimrc Advent Calendar 2017】vimrc で安全に autocmd を設定する【3日目】 - Secret Garden(Instrumental)

カラースキームファイルによる設定

カラースキームを作ったら、その背景色にあう文字色を設定しましょう。

カラースキームの背景が黒に近い場合、デフォルトの色も見やすいと思います。これで十分なら、設定をクリアするだけで簡単です。

unlet! g:terminal_ansi_colors

もっとカラースキームにあった色を設定したい場合は、 g:terminal_ansi_colors を使って色を設定します。ただし、その色設定はカラースキームを後で変更した場合に邪魔かもしれない、という点に注意しましょう。ほかのカラースキームへ変更する時に設定をクリアするようにしてください。

if has('terminal') && exists('##ColorSchemePre')
  let g:terminal_ansi_colors = [
    \ "#0c0c0c", "#c50f1f", "#0f8d64", "#814d25",
    \ "#2353b1", "#881798", "#359fcf", "#cccccc",
    \ "#767676", "#e74856", "#88b422", "#cfa42b",
    \ "#6290ea", "#c800b2", "#44bfe0", "#e8e8e8"
    \ ]

  augroup mycolorscheme
    autocmd!
    autocmd ColorSchemePre * unlet! g:terminal_ansi_colors
    autocmd ColorSchemePre * autocmd! mycolorscheme
  augroup END
endif

自動コマンドグループ名 (:help :augroup) は各自適切に設定してください。

個人的には背景が暗い場合はデフォルトでも十分、背景が明るい場合はデフォルトだと厳しいなと感じます。

関連パッチ

patch 8.0.1685: can't set ANSI colors of a terminal window

patch 8.0.1777: cannot cleanup before loading another colorscheme